genus

Declares a concrete type with fields and methods.

Aliases: class, struct

Syntax: genus <name> [<type-params>] <block>

Category#

type

Related#

• implendum
• abstractus
• implet
• sub

Examples#

radix/corpus/genus/genus.fab (canonical · keyword)#

Declares a concrete type with fields and methods.

# =============================================================================
# genus — Declares a concrete type with fields and methods
# =============================================================================
#
# What this teaches:
#   • Declares a concrete type with fields and methods.
#   • Related keywords: implendum, abstractus, implet, sub
#
# Common mistakes:
#   • Using retired bare object literals (`{ key = expr }`) — use `GenusName { field = expr }` instead; bare `{ }` is now a JSON valor literal.
#
# See also: implendum, abstractus, implet, sub
# =============================================================================

# Basic genus (record type) with fields
#
# genus <Name> {
#     <type> <property>
#     <type> <property> = <default>
# }
#
# GRAMMAR:
#   genusDecl :← 'genus' ident '{' fieldDecl* '}'
#   instance  :← ident '{' fieldInit (',' fieldInit)* '}'
#
# EXPECTED OUTPUT:
#   Field values for Punctum and Persona instances (defaults and overrides).

class Punctum {
    int x
    int y
}

class Persona {
    string nomen
    # default when omitted at instantiation
    int aetas = 0
    bool activus = true
}

main {
    # Instantiate with all required fields
    const _ p ← Punctum {
        x = 10,
        y = 20
    }

    print p.x
    print p.y

    # Instantiate with required + optional defaults
    const _ marcus ← Persona {
        nomen = "Marcus"
    }

    print marcus.nomen
    # 0 from default
    print marcus.aetas
    # verum from default
    print marcus.activus

    # Override defaults explicitly
    const _ julia ← Persona {
        nomen = "Julia",
        aetas = 25,
        activus = false
    }

    print julia.nomen
    print julia.aetas
    print julia.activus
}

Expected output:

10
20
Marcus
0
verum
Julia
25
falsum